Examples

An ordinary $\mathrm{e}^+\mathrm{e}^-$ annihilation event in the continuum, at a c.m. energy of 91 GeV, may be generated with

      CALL PYEEVT(0,91D0)

In this case a $\mathrm{q}\overline{\mathrm{q}}$ event is generated, including weak effects, followed by parton-shower evolution and fragmentation/decay treatment. Before a call to PYEEVT, however, a number of default values may be changed, e.g. MSTJ(101)=2 to use second-order QCD matrix elements, giving a mixture of $\mathrm{q}\overline{\mathrm{q}}$, $\mathrm{q}\overline{\mathrm{q}}\mathrm{g}$, $\mathrm{q}\overline{\mathrm{q}}\mathrm{g}\mathrm{g}$, and $\mathrm{q}\overline{\mathrm{q}}\mathrm{q}' \overline{\mathrm{q}}'$ events, MSTJ(102)=1 to have QED only, MSTJ(104)=6 to allow $\t\overline{\mathrm{t}}$ production as well, MSTJ(107)=1 to include initial-state photon radiation (including a treatment of the $\mathrm{Z}^0$ pole), PARJ(123)=92.0 to change the $\mathrm{Z}^0$ mass, PARJ(81)=0.3 to change the parton-shower $\Lambda$ value, or PARJ(82)=1.5 to change the parton-shower cut-off. If initial-state photon radiation is used, some restrictions apply to how one can alternate the generation of events at different energies or with different $\mathrm{Z}^0$ mass, etc. These restrictions are not there for efficiency reasons (the extra time for recalculating the extra constants every time is small), but because it ties in with the cross-section calculations (see PARJ(144)).

Most parameters can be changed independently of each other. However, if just one or a few parameters/switches are changed, one should not be surprised to find a rather bad agreement with the data, like e.g. a too low or high average hadron multiplicity. It is therefore usually necessary to retune one parameter related to the perturbative QCD description, like $\alpha_{\mathrm{s}}$ or $\Lambda$, one of the two parameters $a$ and $b$ of the Lund symmetric fragmentation function (since they are so strongly correlated, it is often not necessary to retune both of them), and the average fragmentation transverse momentum -- see Note 2 of the MSTJ(101) description for an example. For very detailed studies it may be necessary to retune even more parameters.

The three-gluon and gluon-gluon-photon decays of $\Upsilon$ may be simulated by a call

      CALL PYONIA(5,9.46D0)

A typical program for analysis of $\mathrm{e}^+\mathrm{e}^-$ annihilation events at 200 GeV might look something like

      IMPLICIT DOUBLE PRECISION(A-H, O-Z)
      IMPLICIT INTEGER(I-N)
      INTEGER PYK,PYCHGE,PYCOMP
      COMMON/PYJETS/N,NPAD,K(4000,5),P(4000,5),V(4000,5)
      COMMON/PYDAT1/MSTU(200),PARU(200),MSTJ(200),PARJ(200)
      COMMON/PYDAT2/KCHG(500,4),PMAS(500,4),PARF(2000),VCKM(4,4)
      COMMON/PYDAT3/MDCY(500,3),MDME(8000,2),BRAT(8000),KFDP(8000,5)
      MDCY(PYCOMP(111),1)=0           ! put pi0 stable
      MSTJ(107)=1                     ! include initial-state radiation
      PARU(41)=1D0                    ! use linear sphericity
      .....                           ! other desired changes
      CALL PYTABU(10)                 ! initialize analysis statistics
      DO 100 IEV=1,1000               ! loop over events
        CALL PYEEVT(0,200D0)          ! generate new event
        IF(IEV.EQ.1) CALL PYLIST(2)   ! list first event
        CALL PYTABU(11)               ! save particle composition
                                      !   statistics
        CALL PYEDIT(2)                ! remove decayed particles
        CALL PYSPHE(SPH,APL)          ! linear sphericity analysis
        IF(SPH.LT.0D0) GOTO 100       ! too few particles in event for
                                      !   PYSPHE to work on it (unusual)
        CALL PYEDIT(31)               ! orient event along axes above
        IF(IEV.EQ.1) CALL PYLIST(2)   ! list first treated event
        .....                         ! fill analysis statistics
        CALL PYTHRU(THR,OBL)          ! now do thrust analysis
        .....                         ! more analysis statistics
  100 CONTINUE                        !
      CALL PYTABU(12)                 ! print particle composition
                                      !   statistics
      .....                           ! print analysis statistics
      END